既然有人问是否有比较高效的质数计算方法，那么我就来讲一讲吧

1. 最暴力的算法是O(n^2)的，也就是枚举一个数i在枚举2~i-1判断是否可以整除，这算法也太渣了吧………………
2. 优化一下，由于大于sqrt(i)的因子k都可以表示为i/(i/k)，所以只要枚举到sqrt(i)即可，复杂度O(n^1.5)
3. 继续优化 - 筛法，枚举一个数i，将i的倍数全部筛去（用bool表记录），可以用调和级数证明时间复杂度为O(nlogn)的
4. 终极优化！筛法的缺陷在于一个数会被筛多次，造成速度偏慢，则我们只要让它被最小质因子筛掉即可。也就是程序中的这句话：if i mod Prime[j]=0 then break; 当大于最小质因子的时候（也就是第一次整除的时候）就会被掐掉，这样就使得每个数都只会被筛去一次，时间复杂度降为O(n)

鉴于提问者为Pascal选手，我就用Pascal写一个吧，0-20W的质数表大概在0.01s左右吧（开内存的时间不算……），跑10^9的质数表也很快的。希望我的讲解能对你有所帮助。


program Test;
var
    outf:text;
    n,Total,Ans,i:longint;
    Prime:array[0..30000000]of qword;
    Flag:array[0..Maxlongint shr 1]of boolean;

procedure Main;
var
    i,j:longint;
    Len:longint;
    s:string;
begin
    fillchar(Flag,sizeof(Flag),True);
    Flag[1]:=False;
    Len:=0;
    for i:=2 to n do
    begin
        if Flag[i] then
        begin
            write(outf, i,',');
            str(i,s);
            inc(Len,length(s)+1);
            if Len>150 then
            begin
                Len:=0;
                writeln(outf);
            end;
            inc(Total);
            Prime[Total]:=i;
        end;
        for j:=1 to Total do
        begin
            if Prime[j]*i<=n then Flag[i*Prime[j]]:=False
                        else break;
            if i mod Prime[j]=0 then break;
        end;
        if i mod (n div 10) = 0 then
            writeln(i div (n div 10)*10, ' %');
    end;
end;

begin
    assign(outf,'Result.txt');
    rewrite(outf);
    readln(n);
    Main;
    writeln(outf);
    writeln(outf, Total);
    close(outf);
end.